I can't load this spice file

[ken3663]

Hello all,

I'm new to NI and know nothing about spice files. I found this file doing a google search and I get an errror when I try to use the component wizard. Below is the file ,could someone tell what is wrong with it. I don't understand the error message.

Thanks for any help,

Ken

C:\spice8\Circuits\ON\33063\apptest.cir Setup1
*#save @V1[i] @V1[p] V(16) @L1[i] @D1[id] @D1[p] @R5[i] @R5[p]
*#save @R6[i] @R6[p] @C5[i] V(17) @V6[i] @V6[p] @R11[i] @R11[p]
*#save V(2) V(5) V(6) V(1) V(ct) @R1[i] @R1[p] @C6[i]
*#alias vo  v(16)
*#view  tran vo
*#view  tran iy9
*#alias iy9 @v6[i]
.TRAN .5u 8m 0 .5u UIC
.OPTIONS abstol=.001 itl4=1000
.OPTIONS reltol=0.001
.PRINT  TRAN vo
.PRINT  TRAN IY9
V1 2 0 DC=25
L1 5 16 220u
D1 0 5 DN5819
.MODEL DN5819 D BV=5.33E+01 CJO=1.44E-10 EG=0.69
+ IBV=6.00E-04 IS=1.65E-05 M=.671 N=1.41 RS=4.47E-02
+ TT=7.20E-11 VJ=1.45 XTI=2
R5 16 6 3.6k
R6 6 0 1.2k
C5 16 0 220u IC=5
V6 17 0
R11 16 17 10
X1 1 5 ct 0 6 2 1 1 MC33063 {  }
.SUBCKT MC33063 swc    swe    ct    90    2    vdd    isns    drc
*               SW-col SW-em  Ct    gnd    cinv vdd    isns    drive col
*DC-DC controller
B2 5 90 V=~(v(9)&v(8))
Q1 drc 15 13 QN2222A
.MODEL QN2222A NPN BF=205 BR=4 CJC=15.2P CJE=29.5P IKF=.5
+ IKR=.225 IS=81.1F ISE=10.6P NE=2 NF=1 NR=1 RB=1.37 RC=.137
+ RE=.343 TF=397P TR=85N VAF=113 VAR=24 XTB=1.5
B3 7 90 V=~(v(4)&v(10))
R1 5 10 100
R9 13 swe 100
C2 10 90 10p IC=5
R7 2 90 1MEG
R2 7 8 100
C3 8 90 10p IC=0
S2 srst 90 ct 90 _S2_mod 
.MODEL _S2_mod SW VT=1.25 VH=.4
R3 srst vdd 100k
V3 vref 90 DC=1.25
B4 6 90 V=v(2)  > (v(vref) + v(voff))  ? v(90) : v(vdd)
B1 vdd ct I=V(srst) > 2.5 ? 35U : -220U
B5 9 90 V=v(6) > 2.5 ? v(11) > 2.5 ? v(90) : v(vdd)
R4 4 11 100
C4 11 90 10p IC=5
B6 15 90 V=v(5) > 2.5 ? v(vdd) : v(90)
Q2 swc 13 swe QN5190
.MODEL QN5190 NPN BF=144 BR=4 CJC=3.1E-10 CJE=3.1E-10
+ IKF=300M IRB=416.67U IS=4.65E-12 ISC=5N ISE=7.62E-10
+ ITF=3.6 MJC=210M MJE=300M NE=2.0 NF=1.0 NR=1.0 PTF=120
+ RB=12.0 RBM=1.2 RC=6.8E-02 RE=1.7E-01 TF=4.5E-08 TR=1.27U
+ VAF=114 VAR=20 VJC=1.25 VJE=500M XTB=2.5 XTF=1
V4 voff 90 DC=2m
B7 4 90 V=(v(vdd) - v(isns)) < v(iref) ? (v(srst) > 2.5) ? v(vdd) : v(90)
R10 vdd isns 1MEG
V5 iref 90 DC=300m
.ENDS
R1 1 2 .33
C6 ct 0 470p IC=.85
.END

[Chen_T]

Hi Ken,

The file you post (apptest.cir)is not the Spice Model file, you should use the following 02FEB18 MC33063 HYMOVITZ.LIB file as your Model. This file can be found on the ON Semiconductor Website:

*==========================================================
* MC34063
* ON SEMICONDUTOR
* 1.5 A, Step-Up/Down/Inverting Switching Regulator
*
* This model was developed for On Semiconductor by:
* AEI Systems, LLC
* 5777 W. Century Blvd. Suite 876
* Los Angeles, California 90045
* Copyright 2002, all rights reserved.
*
* This model is subject to change without notice.
* Users may not directly or indirectly re-sell or
* re-distribute this model. This model may not
* be used, modified, or altered
* without the consent of On Semiconductor.
*
* For more information regarding modeling services,
* model libraries and simulation products, please
* call AEi Systems at (310) 863-8034, or contact
* AEi by email: info@aeng.com. http://www.AENG.com
*
* Revision: 2/18/02, version 1.1
*==========================================================
**********
*src=MC33063;MC33063;Regulators;On Semiconductor;1.5A
*SYM=MC34063
.SUBCKT MC33063 swc swe ct 90 2 vdd isns drc
* SW-col SW-em Ct gnd cinv vdd isns drive col
*DC-DC controller
B5 5 0 V=~(v(9)&v(8))
Q1 ct isns vdd QN2907
.MODEL QN2907 PNP BF=200 BR=6 CJC=19PF CJE=23PF IKF=100E-3
+ IS=1.1E-12 ISE=1.3E-11 MJC=.2 MJE=1.25 NE=1.9 NF=1.21 RC=.6
+ TF=5E-10 TR=34E-9 VAF=50 VJC=.5 VJE=.85 XTB=1.5
B6 7 0 V=~(v(4)&v(10))
R3 5 10 100
R9 13 swe 100
C2 10 0 100p IC=5
R4 2 90 10MEG
R5 7 8 100
C3 8 0 100p IC=0
S1 srst 90 ct 90 _S2_mod
.MODEL _S2_mod SW VT=1.75 VH=1.25
R1 srst vdd 10k
Q2 drc 14 13 _Q3_mod
.MODEL _Q3_mod NPN BF=50
B4 6 0 V=v(2,90) > (v(vref,90) + v(voff,90)) ? 0 : v(vdd)
B2 vdd ct I=V(srst,90) > 3 ? 35U : -220U
B3 9 0 V=(v(6,90) > 3) ? v(diff,90) > 1 ? 0 : v(vdd)
B7 16 90 V=V(vdd,90)-1.5 > 1.25 ? 1.25 : V(vdd,90)-1.25 < 0 ? 0 :V(vdd,90)-1.25
V7 16 vref
R6 vref 90 400
R7 vref vdd 90k
Q1x swc 13 swe _Q4_mod
.MODEL _Q4_mod NPN BF=50 RC=.25 RE=.25 TF=0
R8 diff 90 10k
D1 14 15 DN4148
.MODEL DN4148 D BV=100V CJO=4PF IS=7E-09 M=.45 N=2 RS=.8
+ TT=6E-09 VJ=.6V
D2 swe 14 DN4148
V3 drc 15 DC=700m
B8 swe 14 I=v(5) > 2.5 ? 1m : -1m
V4 voff 90 DC=2m
C5 srst diff 10p
B1 4 90 V=(v(6,90) > 3) ? (v(diff,90) > -1) ? v(vdd) : 0
R10 vdd isns 10k
.ENDS
**********

I've attached the LIB file for you. Also, please note that MC34063 and MC33063 share the same model file which means we don't need to create the MC33063 componnet, we can just use the MC34063 that Multisim 13 has already built within.

Hope it helps!:-)

Regards,

[Tien_P]

Hi Ken,

This is a circuit netlist and not a single component model, using the Component Wizard to import this netlist is not correct. What you should use instead is the Arbitrary Spice Block, this is a component found in the database and it allows you to import an entire circuit netlist without drawing a schematic in Multisim. This part is located in the "Basic" group under the "Basic Virtual" family.

The netlist have three things, the commands the run the Transient Analysis, which node to look at and the circuit netlist itself. You only need to copy the circuit netlist which begins at this line:  V1 2 0 DC=25, copy everything to the last .end line. When you place the Arbitrary SPICE block on the work, double click on it and you can paste the circuit netlist into the box.

Multisim should understand the netlist and you are ready to run the Transient Analysis which is under the menu Simulate>>Analysis>>Transient. The netlist Transient settings are different than Multisim default and you don't need make any changes but if you want to match the setting, you can refer to the transient section from this link to understand the syntax:

http://www.seas.upenn.edu/~jan/spice/spice.overview.html#Transient

.TRAN .5u 8m 0 .5u UIC
.OPTIONS abstol=.001 itl4=1000
.OPTIONS reltol=0.001

Click on the "Output" tab in the Transient Analysis dialog and you should see the nodes and current branches from the netlist.  

This line in the netlist : @V1[i]  = current through a voltage source V1

.

[ken3663]

Thank you Chen and Tien.

Regards,

Ken