Property Information When Using DataFileLoad and DataFileLoadSel

[smoothdurban]

Hi

When I load data using the DataFileLoad command DIAdem creates a new group with the file name and I have access all of the custom data properties.  However when I use the DataFileLoadSel command I specify which channels I want loaded but the new data group does not retain any of the custom data file properties.

Is this behavior expected?  If so is there away for me to load custom data file properties when using the DataFileLoadSel command?

[Walter_Rick]

Hi smoothdurban.

Yes, this is expected. The default is that DIAdem just loads the properties for the object (and below) you selected (Root or Group or Channel). But you can specify whether the properties from higher levels should also be loaded.

Greetings

Walter

[AndreasK · Accepted solution]

You can use some kind of auto class to get a loadingbehavior that is not dependent on the settings.

call Load()

Sub Load()
  dim AutoLoadMode : set AutoLoadMode = new CAutoLoadMode
  call DataFileLoadSel("example.tdm",,"[1]/[2,3]")
end sub

class CAutoLoadMode
  Private Sub Class_Initialize()
    ' save old values
    PropInheritanceModeDF_     = PropInheritanceModeDF   
    PropInheritanceMode_       = PropInheritanceMode     
    PropNamingSchema_          = PropNamingSchema        
    BulkDataLoadingMode_       = BulkDataLoadingMode     
    ChnCharacteristicsUpdate_  = ChnCharacteristicsUpdate
    ' set your defaults
    PropInheritanceModeDF = "MoveToLoadedLevel"
    PropInheritanceMode = "MoveToLoadedLevel"
    PropNamingSchema = "TypeNamePropertyName"
    BulkDataLoadingMode = eBulkDataLoadingImmediately
    ChnCharacteristicsUpdate = "Automatic"
  End Sub
  
  Private Sub Class_Terminate()
    ' set back old values
    PropInheritanceModeDF    = PropInheritanceModeDF_   
    PropInheritanceMode      = PropInheritanceMode_     
    PropNamingSchema         = PropNamingSchema_        
    BulkDataLoadingMode      = BulkDataLoadingMode_     
    ChnCharacteristicsUpdate = ChnCharacteristicsUpdate_
  End Sub

  private PropInheritanceModeDF_
  private PropInheritanceMode_
  private PropNamingSchema_
  private BulkDataLoadingMode_
  private ChnCharacteristicsUpdate_
end class

The available parameters can always be retrieved using CTRL+Shift+C in the settings dialog which will put them into clipboard.

[smoothdurban]

This will do the trick.

Thanks