Multisim and Ultiboard

cancel
Showing results for 
Search instead for 
Did you mean: 

model for UC2842 or UC3842

Highlighted
Does anybody have the model(extension .txt) for the UC2842/2843/2844/2845 or UC3842/3843/3844/3845
Anyone of these models would be apreciable.
0 Kudos
Message 1 of 4
(4,391 Views)
Highlighted
Hi,
 
Here is a model for the Model for the UC3842.
 
.subckt UC3842 comp VFB isens RAC 0 out vcc ref1
.ic v(RAC)=0
azener1 0 vcc zener1
vlow vlow1 0 dc 10
vhigh vhigh1 0 dc 16
xuvlol vlow1 vcc uvsa1 op1
xuvloh vcc vhigh1 uvra1 op1
aadc1 [uvsa1] [uvs1] ADC1
aadc2 [uvra1] [uvr1] ADC1
xuvff uvs1 uvr1 uvq1 uvqb1 srff1
adacref [uvqb1] [uvqb2] DAC1
ruvqb uvqb2 0 1meg
eref REFV 0 uvqb2 0 1
rref REFV 0 1
aadcref [REFV] [ref11] ADC2
gcur vcc 0 REFV 0 0.0022
vref ref1 0 dc 5
idc em1 0 5.1814m
didc 0 em1 dmod
eosl1 osh1 0 ref1 0  0.56
eosh1 osl1 0 ref1 0  0.24
xosl1 RAC osh1 osr1 op1
xosh1 osl1 RAC oss1 op1
aosadc1 [osr1] [osr2] ADC1
aossdc2 [oss1] [oss2] ADC1
xosff1 oss2 osr2 osq1 osqb1 srff1
aosdac1 [osqb1] [gdc2] DAC1
egdc1 gdc1 0 gdc2 0 1
src1 RAC em1 gdc1 0 sw1
ainv1 uvqb1 uvqb10 inv1
aref12 ref11 ref12 inv1
aor1 [ref12 osqb1] logout1 or1

Vvref 3 0 dc 5
rR2 2 0  1e+006
rR1 3 2  1e+006
xU1 2 VFB comp 7 6 OP4
vV4 0 6 dc 15
vV3 7 0 dc 15
d1 comp 131 dmod
d2 131 132 dmod
r132 132 133 20k
rR4 133 0  10k
azener2 0 133 zener2
xcmod1 isens 133 cmod1 op1
rcmod1 cmod1 0 1meg 
acmodadc [cmod1] [cout1] ADC1
xoutsrff osqb1 cout1 out1q1 out1qb1 srff1

aoutor1 [ref12 out1qb1] out1qb2 or1
aoutor2 [out1qb2 logout1] out1 or1
aoutinv1 out1 out2 inv1
aoutdac [out2] [out] DACOUT
rout out 0 1k
 

.model zener2 zener(v_breakdown=1.0)
.model dmod d(n=1.05)
.SUBCKT         op4 3 2 6 7 4
* 3     2     6     7      4
* +in   -in   out   Vcc    Vee
Rc1 7 11 5.305e+003
Rc2 7 12 5.305e+003
Re1 13 15 4.594e+003
Re2 14 15 4.594e+003
RE 15 0 1.319e+007
IEE 15 4 1.516e-005
Rp 7 4 1.816e+004
VC 7 16 1.080e+001
VE 17 4 1.230e+001
D4 17 6 dmod34
D3 6 16 dmod34
R01 18 6 3.213e+001
R02 18 0 4.287e+001
RC 19 0 1.369e-004
C1 11 12 9.741e-012
Ce 15 0 1.000e-012
C2 18 20 3.000e-011
R2 0 20 1.000e+005
D1 18 19 dmod12
D2 19 18 dmod12
Ga 20 0 11 12 1.885e-004
Gcm 0 20 15 0 5.961e-009
Gb 18 0 20 0 3.913e+001
Gc 0 19 18 0 7.304e+003
.MODEL dmod12 D(IS=1.877e-012)
.MODEL dmod34 D(IS=8.000e-016)
Q1 11 2 13 QMOD1
Q2 12 3 14 QMOD2
.MODEL QMOD1 NPN(IS=8.0e-16 BF=8.333e+001 VAF=200)
.MODEL QMOD2 NPN(IS=8.0e-16 BF=1.071e+002 VAF=200)
.ends

.model sw1 sw(vt=4 vh=0.5 ron=1e-6 roff=1e12)
.model or1 d_or()
.model inv1 d_inverter()
*.model inv2 d_inverter(rise_delay=50n fall_delay=50n)
.model zener1 zener(v_breakdown=34)
.model dmod d(n=0.001)
.model ADC1 adc_bridge(in_low=0.3 in_high=3)
.model ADC2 adc_bridge(in_low=3 in_high=4)
.model DAC1 dac_bridge(out_low=0  out_high=5)
.model DACOUT dac_bridge(out_low=0.1  out_high=13.5)
.subckt srff1 1 2 3 4
as1 1 11 inv1
ar1 2 21 inv1
anand1 [11 4] 3 nand1
anand2 [21 3] 4 nand1
.model nand1 d_nand()
.model inv1 d_inverter()
.ends srff1

.SUBCKT OP1  1 2 3
* 1->in+, 2->in-, 3->out
    Vos 4 1 DC 0V
    Ib1 4 0 0A
    Ib2 2 0 0A
    G1 0 5 4 2 0.1
    G2 0 6 5 0 100
    G3 0 31 6 0 100
    RR 31 0 1
    alimit 31 3 limit1
    .model limit1 limit(out_lower_limit=-5 out_upper_limit=5)
    Ri 4 2 1e+010ohm
    R1 5 0 1000ohm
    R2 6 0 1ohm
    R3 3 0 1ohm
    C1 5 0 1.59155e-010
    C2 6 0 1.59155e-033
.ENDS
.ends

 
Tien P.

National Instruments
0 Kudos
Message 2 of 4
(4,344 Views)
Highlighted
dear friend,
thanks a lot for the model of uc3842, but i do not know how to use it. please can you guide me to know how to create a model of uc3842 from it.
thanks in advance.
0 Kudos
Message 3 of 4
(4,306 Views)
Hi,
 

Have a look at this link it is a step by step instruction for create a new component.

 
Regards,
 
Tien Pham
EWB Support
Tien P.

National Instruments
0 Kudos
Message 4 of 4
(4,299 Views)