lm137 model behavior

[max1000000]

I have a spice model for a LM137 negative voltage regulator which I obtained from a McGill website (http://www.rcsm.ece.mcgill.ca/~rfic/EC2/SPICE_MODEL_LIB.htm). I have developed a simulation using this device as well as the standard LM117 provided by multisim to regulate a positive/negative DC source. It works well. (The model for the 137 is considerably more complex that the 117).

Now then, when I replace the DC power with a rectified AC source the simulation aborts with a timestepping error. When I switch the LM137 out, the simulation runs. adding big filter caps dosn't help.

However, ifI run the simulation with a DC source for a short while then switch out the DC and switch in the AC simultaneously then the simulation is correct. 

Can anyone tell me (I'm a student not a guru) what is happening and how to fix the problem. The LM137 model is below.

* MANUFACTURERS PART NO. = LM137HVH (NATIONAL SEMICONDUCTOR)
* SUBTYPE: REGULATOR
*
* THIS FILE CONTAINS A PRE-RAD MODEL AT 27 C OF THE LM137HVH THAT WAS
* DEVELOPED UNDER THE GUIDANCE OF GREGORY M. WIERZBA AT
* MICHIGAN STATE UNIVERSITY.
*
* PLEASE NOTE THE FOLLOWING:
*
* 1) THIS MODEL IS TO BE USED FOR ROOM TEMPERATURE SIMULATIONS. THE BUILT-
* IN SPICE TEMPERATURE CORRECTIONS WILL NOT WORK.
* 2) RIPPLE REJECTION, OUTPUT IMPEDANCE, LINE TRANSIENT, AND LOAD
* TRANSIENT RESPONSE ARE MODELED BASED ON LABORATORY
* MEASUREMENTS. THE CORRELATION IS QUITE GOOD. THE SIMULATION VALUES
* ARE WITHIN THE PRODUCT SPEC LIMITS.
* 3) CURRENT LIMITING AND ADJUSTMENT CURRENT BASED ON DATA SHEET
* INFORMATION ARE MODELED ACCURATELY.
* 4) DROPOUT AND POWER UP CHARACTERISTICS HAVE NOT BEEN DEVELOPED YET
* IN THIS MODEL.
* 5) FOR FURTHER DETAILS AND THE MODEL DERIVATION, OBTAIN A COPY OF
* "CA3085, LM7805, LM7812, LM7905, LM137 MACROMODEL DEVELOPMENT" BY G. M.
* WIERZBA DATED 3/25/91.
*
*
*
.SUBCKT LM137HVH 1 2 3
* IN | |
* OUT |
* ADJ
*
VREF 12 4 DC 1.25
EREG 3 12 1 2 0.0001981
IBIAS 4 1 DC 65U
RIN 4 20 100MEG
E1 5 1 20 4 600
R1 5 6 1561
RPZ 6 11 0.01
C1 11 1 1U
E2 7 1 6 1 1
RB1 7 17 25
RB2 17 8 50
DLIMIT 17 18 DMOD
ELIMIT 18 1 POLY (1) (2,1) .24 -0.0024
DFLDBCK 17 19 DMOD
EFLDBCK 19 1 POLY(1) (2,1) 1.0611 -0.0912 0.0026 -2.5E-5
CBC 8 9 1U
RBC 9 20 1561
QPASS 20 8 1 QMOD
RBOND 20 2 0.0063
.MODEL QMOD NPN(
+ IS = 1E-16
+ BF = 500
+ NF = 1
+ VAF = 150
+ IKF = 9.9999E+13
+ ISE = 0
+ NE = 1.5
+ BR = 1
+ NR = 1
+ VAR = 9.9999E+13
+ IKR = 9.9999E+13
+ ISC = 0
+ NC = 2
+ RB = 0
+ IRB = 9.9999E+13
+ RBM = 0
+ RE = 0
+ RC = 0
+ CJE = 0
+ VJE = .75
+ MJE = .33
+ TF = 0
+ XTF = 0
+ VTF = 9.9999E+13
+ ITF = 0
+ PTF = 0
+ CJC = 0
+ VJC = .75
+ MJC = .33
+ XCJC = 1
+ TR = 0
+ CJS = 0
+ VJS = .75
+ MJS = 0
+ XTB = 0
+ EG = 1.11
+ XTI = 3
+ KF = 0
+ AF = 1
+ FC = .5
+ )
.MODEL DMOD D(
+ IS = 1E-15.9
+ RS = 0
+ N = 1
+ TT = 0
+ CJO = 0
+ VJ = 1
+ M = .5
+ EG = 1.11
+ XTI = 3
+ KF = 0
+ AF = 1
+ FC = .5
+ BV = 9.9999E+13
+ IBV = .001
+ )
.ENDS LM137HVH
*$

[max1000000]

Answered my own question. For the knowledge base, RC snubbers on the power supply did the trick.

Evidently the more simple model used for the positive regulator was immune to the effect.