Hello,
I downloaded the SPICE model files of the UJ4N75004 component from the onsemi company's website. They are attached below in a .rar file.
How can I import these into the Multisim 14.3 program? Could you please assist me?
Thanks & Regards
Here;
********************************************************************************
* Qorvo G4 750V-4mohm SiC JFET Spice Circuit Model v1.0
* Copyright 2024 Qorvo
*
*
* The model does not include all possible conditions and effects,
* in particular it doesn't include:
* Self heating
* leakage current in blocking state
* Drain to source breakdown is notional only
*
********************************************************************************
*** UJ4N075004L8S ***
.subckt UJ4N075004L8S nd ng ns nss
Ld nd nd2 5n
Rd nd2 nd1 0.8m
Lg ng ng1 4n
Ls ns ns1 2n
Rss nss ns1 1u
xj1 nd1 ng1 ns1 jfet_G4_750V_Ron_UJ4N075004 params: Ron=4m Rg=0.8
.ends
*** 750V JFETs ***
.subckt jfet_G4_750V_Ron_UJ4N075004 d g s params: Ron=0 Rgon=0 Rgoff=0
.param Ron1={Ron}
.param Rg1={Rg}
.param a= {10m/{Ron1}}
X1 di gi s jfet_G4_750V_UJ4N075004 params: ascale={a}
XCgs gi s Cgs_G4_750V_UJ4N075004 params: acgs={a}
XCgd gi di Cgd_G4_750V_UJ4N075004 params: acgd={a}
Rd d di Rtemp {7m/{a}}
.MODEL Rtemp RES (TC1=6.060e-3, TC2=3.2e-5)
Rg g gi {Rg1}
.ends jfet_G4_750V_UJ4N075004
.subckt jfet_G4_750V_UJ4N075004 d g s Params: ascale=0
.param Fc1=0.5
.param Pb1=3.25
.param M1=0.5
.param Vd0=400
.param Vg0=25
.param gos={0.228*{ascale}}
.param gfs={191.0*{ascale}}
.param f=1.763
.param vth=-5.3
.param cgs1={0.475n*{ascale}}
.param cgd1={0.136n*{ascale}}
.param bt={({f}*{gfs}+2*{gos}*{Vd0}/{vth})/2/(-{vth})}
.param lamd={1*{gos}/{bt}/{vth}/{vth}}
.param cgs0={pwr((1+{Vg0}/{Pb1}),{M1})*{cgs1}}
.param cgd0={pwr((1+{Vd0}/{Pb1}),{M1})*{cgd1}}
J1 d g s jfet_750
Dgs g s Dgs_iv
Dgd g d Dgd_iv
Rgs g s 1Meg
Rgd g d 10Meg
.MODEL jfet_750 NJF(
+ Beta={{bt}} BetaTce=-0.5 Vto={vth} VtoTc=-3e-3 lambda={lamd}
+ Is=1e-60
+ Cgs={cgs0} Cgd={cgd0} Fc={Fc1} Pb={Pb1}
+ M={M1})
.MODEL Dgs_iv D (CJO=0 BV=120 IS=1e-50 ISR=1e-50 Eg=3.5 Rs=0)
.MODEL Dgd_iv D (CJO=0 BV=900 IBV=1m IS=1e-50 ISR=1e-50 Eg=3.5 Rs={18.9m/{ascale}})
.ends jfet_G4_750V
* Cgs network
.subckt Cgs_G4_750V_UJ4N075004 g s params: acgs=0
.param c0=1n
.param vsgmin=-2
.param vsgmax=15
.param a1={1.2*3n*{acgs}}
.param b1=0.1
.func Qgs1(u) {- {a1} / {b1} *(exp(- {b1} *u)-1)}
.param a2={0*{acgs}}
.param b2=0.5
.param c2=8.7
.func Qgs2(u)
+ {if(abs(u)<{vsgmax},
+ {a2}*u + {a2}*(-{b2})*log(cosh((u-{c2})/-{b2}))
+ -{a2}*(-{b2})*log(cosh(-{c2}/-{b2})),
+ {a2}*{vsgmax} + {a2}*(-{b2})*log(cosh(({vsgmax}-{c2})/-{b2}))
+ -{a2}*(-{b2})*log(cosh(-{c2}/-{b2})))}
E1 s m1 value={v(s,g)-Qgs1(v(s,g))/{c0}}
C01 m1 g {c0}
E2 s m2 value={v(s,g)-Qgs2(limit(v(s,g),-{vsgmax},{vsgmax}))/{c0}}
C02 m2 g {c0}
.ends Cgs_G4_750V_UJ4N075004
* Cgd network
.subckt Cgd_G4_750V_UJ4N075004 g d params:acgd=0
.param c0=1n
.param a1={1.2*0.5n*{acgd}}
.param b1=2
.param c1=14
.param vdgmax1=50
.func Qgd1(u)
+ {if(abs(u)<{vdgmax1},
+ {a1}*u + {a1}*(-{b1})*log(cosh((u-{c1})/-{b1}))
+ -{a1}*(-{b1})*log(cosh(-{c1}/-{b1})),
+ {a1}*{vdgmax1} + {a1}*(-{b1})*log(cosh(({vdgmax1}-{c1})/-{b1}))
+ -{a1}*(-{b1})*log(cosh(-{c1}/-{b1})))}
.param a2={0*{acgd}}
.param b2=0.5
.param c2=6
.param vdgmax2=15
.func Qgd2(u)
+ {if(abs(u)<{vdgmax2},
+ (-1)*({a2}*u + {a2}*(-{b2})*log(cosh((u-{c2})/-{b2}))
+ -{a2}*(-{b2})*log(cosh(-{c2}/-{b2}))),
+ (-1)*({a2}*{vdgmax2} + {a2}*(-{b2})*log(cosh(({vdgmax2}-{c2})/-{b2}))
+ -{a2}*(-{b2})*log(cosh(-{c2}/-{b2}))))}
E1 d m1 value={v(d,g)-Qgd1(limit(v(d,g),-{vdgmax1},+{vdgmax1}))/{c0}}
C01 m1 g {c0}
E2 d m2 value={v(d,g)-Qgd2(limit(v(d,g),-{vdgmax2},+{vdgmax2}))/{c0}}
C02 m2 g {c0}
.ends Cgd_G4_750V_UJ4N075004
*** End of File ***
