MAT02 SPICE MODEL

[Equinox-fryslan]

I ran into a problem concerning the modeling off a MAT02 DUAL transistor in the Multisim 8.0 package.

How do i assign pin number 7 into a component with 6 pins. The pin-assignment of the second transistor starts with pin number 5

Assignment       Pin number 

C1                      1

B1                      2

E1                      3

E2                      5     

B2                      6

C2                      7

Look at the MAT02 Spice Model:

  MAT02 SPICE Macro-model                 4/90, Rev. A
*                                          DFB / PMI
*
* Copyright 1990 by Analog Devices, Inc.
*
* Refer to "README.DOC" file for License Statement.  Use of this model
* indicates your acceptance with the terms and provisions in the License Statement.
*
* Node assignments
*              C1
*              | B1
*              | | E1
*              | | | E2
*              | | | | B2
*              | | | | | C2
*              | | | | | |
.SUBCKT MAT02  1 2 3 5 6 7
Q1   1  2  3   NMAT
Q2   7  6  5   NMAT
D1   3  2      DMAT1
D2   5  6      DMAT1
D3   4  3      DMAT1
D4   4  5      DMAT1
D5   4  1      DMAT2
D6   4  7      DMAT2
.MODEL    DMAT1  D(IS=2E-16 RS=20)
.MODEL    DMAT2  D(IS=1E-14 VJ=0.6 CJO=40E-12)
.MODEL    NMAT NPN(BF=500 IS=6E-13 VAF=150 BR=0.5 VAR=7
+ RB=13 RC=10 RE=0.3 CJE=82E-12 VJE=0.7 MJE=0.4 TF=0.3E-9
+ TR=5E-9 CJC=33E-12 VJC=0.55 MJC=0.5 CJS=0 IKF=0.300
+ PTF=25)
.ENDS

[nestor-sg]

In Multisim -- I don't know for other spice simulator --, when assigning the pin numbers... you assign them in the order that they appear in the ".subckt" line. Since that is the order of the mapping procedure into a symbol.

Let me be more clear...  your first line is like:

.SUBCKT MAT02  1 2 3 5 6 7

So, when mapping to a symbol that has 6 pins... spice sees the above line as 1, 2, 3, 4, 5, 6. Your assignment should then be:

Assignment       Pin number 

C1                      1

B1                      2

E1                      3

E2                      5   << 4  

B2                      6   << 5

C2                      7   << 6

Inside the SPICE code, it will still be 1, 2, 3, 5, 6, 7.... but from the symbol it will take those signals from 1, 2, 3, 4, 5, 6. In that order. Another example for this is, suppose that first line has these pins... 1, 13, 4, 6, 9, 10..... when you map them, you will still map them considering that 1 is 1, 13 is 2, 4 is 3, 6 is 4, 9 is 5 and 10 is 6.

I hope this helps....

[Equinox-fryslan]

The problem is solved, the model works now.

Thank you for the support.

best regards,

Willem

The Netherlands