import NxP Spice model for a buffer into Multisim

[dan.iel]

Hello 2 all!

I have downloaded a zip file from NxP which includes some librarys and a cir file. in this librarys there are all kind of buffers. but i need two specific buffers (non inverting and inverting buffer with open drain output --> INVERT10  and  INVERT10N in my circuit design.

i tried to make a new component by adding the spice SUBCKT in the textfield and by assigning the right pins, but in the simulation the buffer will not do his work. i am sure that the "importing" of the spice directives was wrong.

can maybe someone make me a favour and try it?

the zip file can be found here  http://www.standardics.nxp.com/support/models/spice/  --> (LVC)

it would be really helpful for me, also for further imports from NxP.

thank you,

Daniel

[_user32]

dan.iel ,

I think you may be missing some model definitions.  These are hierarchical model libraries (*.lib) formatted for Orcad, however they can still be used to create a model in Multisim.   They can be opened in Wordpad or Notepad - I find the best formatting with Wordpad.

Here is what you need to do to get these parts working in Multisim...  lets take the case of invert10...

1. Choose which mode of operation you want to use... nominal, fast, slow... I'll assume nominal will be preferred (lvcnom.lib).  It looks like the use of different Mosfet models are used to describe the parts operation over the variance of the specification.

2. Open up a new text document and copy the INVERT10 model out of here and into this new document.   Notice it references other parts with an "X" reference designator... specifically "XIN1", "XINV1", "XOUT" and "XPAK14" - these are other subckt models that also need to be included within the Multisim model directly.

3.  XIN1 relates to the LVCINPAN model, XINV1 relates to the LVCINVAN model and XOUT relates to the LVCOUTODN - these .subckt definitions are found at the top of this 'lvcnom.lib' document.  Copy these parts in their entirety (.subckt to .ends) after the first .subckt definition you created for your newly created INVERT10 part model.

4. The "XPAK14" is referencing the PAK14 package model file - these are the "*.s" documents.  Specifically open up the "so.s" and you will find the package model for the PAK14 model.   I believe these are used for modeling the package/wirebond parasitics.

5. Finally you will need to copy the MPEN and MNEN mosfet models from the lvcnom.lib and place these after these .subckt definitions...   So your model will generally look like this...

.SUBCKT INVERT10    2  4  1  90

<rest of model>

.ENDS

.SUBCKT  LVCINPAN ...

<rest of model>

.ENDS

.SUBCKT  LVCINVAN...

<rest of model>

.ENDS

.SUBCKT  LVCOUTODN...

<rest of model>

.ENDS

.SUBCKT PAK14 ...

<rest of model>

.ENDS

.MODEL MNEN NMOS

<rest of model>

.MODEL MPEN PMOS

<rest of model>

6. Use the Multisim Component Wizard to finish creating the part and map the symbol pins to the top level model pins for the INVERT10 model.   Again the tedious part is convertign this heirarchical format into a flattened model.

Regards,

Patrick Noonan
Business Development Manager
National Instruments - Electronics Workbench Group
50 Market St. 1-A
S. Portland, ME 04106
Email: patrick.noonan@ni.com
Tel. (207) 892-9130
Fax. (207) 892-9508 

[dan.iel]

Hello Patrik!

thank you for your response.

I really tried a few times to import the model as you described it. after the model is in the library, i can put it in my circuit, but it does nothing. when i add the output signal to my transient analisis, the analisis results blank and also all other signals will disappear.

here i post you my model

 
##################  Model  ##################

.SUBCKT INVERT10      2  4  1  90
* INVERTING BUFFER TYPE; OPEN DRAIN
* EQUIVALENT REFERENCE SIMULATION MODEL FAST CASE
* USE THIS MODEL FOR 74LVC06
* IN = 2,  OUT = 4,  VCC = 1,  GND = 90
* MAY-2005
XIN1   20  30  50  60      LVCINPAF
XINV1  30  35  50  60      LVCINVAF
XOUT   35  40      60      LVCOUTODF
XPK14 2  4 90 90 90 90 90 90 90 90 90 90 90  1
+    20 40 90 90 90 90 60 90 90 90 90 90 90 50 pk14
.ENDS

.SUBCKT LVCINPAF   2   3   50   60
* FAST CASE PARAMETERS
* STANDARD LVC INPUT P-CH 150/0.8 N-CH 70/0.8 INCL. ESD STRUCTURE
* IN = 2,  OUT = 3,  VCC = 50,  GND = 60
* SEPTEMBER-1994
MN1 2 60 60 60 MNEF W=400U L=1.0U AD=7390P AS=208P PD=688U PS=420U
R1  4  2  100
MN2 4 60 60 60 MNEF W= 43U L=1.0U AD=176P AS=208P PD= 58U PS= 58U
MP1 3  4 50 50 MPEF W=150U L=0.8U AD=220P AS=400P PD=175U PS=175U
MN3 3  4 60 60 MNEF W= 70U L=0.8U AD= 80P AS=170P PD= 80U PS= 80U
MP2 5  3 50 50 MPEF W= 10U L=0.8U AD= 22P AS= 22P PD= 25U PS= 25U
MN4 5  3 60 60 MNEF W=  4U L=0.8U AD=  9P AS=  9P PD= 12U PS= 12U
MN5 3  5 60 60 MNEF W= 22U L=1.6U AD= 40P AS= 40P PD= 40U PS= 40U
.ENDS

 
.SUBCKT LVCINVAF   2   3   50   60
* FAST CASE PARAMETERS
* INTERNAL INVERTER P-CH 30/0.8  N-CH 12/0.8
* IN = 2,  OUT = 3,  VCC = 50,  GND = 60
* SEPTEMBER-1994
MP1 3  2 50 50 MPEF W= 30U L=0.8U AD=35P AS=35P PD=35U PS=30U
MN1 3  2 60 60 MNEF W= 12U L=0.8U AD=30P AS=30P PD=20U PS=15U
.ENDS
 

.SUBCKT LVCOUTODF    3   4  60
* FAST CASE PARAMETERS
* OPEN DRAIN OUTPUT MODULE (ONLY N-CHANNEL)
* IN = 3,  OUT = 4,  GND = 60  
* MAY-2005
R0   4  40 24
MN0  40 3  60  60 MNEF W=52U L=0.65U AD=80P AS=80P PD=80U PS=80U
R1   4  41 24
MN1  41 3  60  60 MNEF W=52U L=0.65U AD=80P AS=80P PD=80U PS=80U
R2   4  42 24
MN2  42 3  60  60 MNEF W=52U L=0.65U AD=80P AS=80P PD=80U PS=80U
R3   4  43 24
MN3  43 3  60  60 MNEF W=52U L=0.65U AD=80P AS=80P PD=80U PS=80U
R4   4  44 24
MN4  44 3  60  60 MNEF W=52U L=0.65U AD=80P AS=80P PD=80U PS=80U
R5   4  45 24
MN5  45 3  60  60 MNEF W=52U L=0.65U AD=80P AS=80P PD=80U PS=80U
R6   4  46 24
MN6  46 3  60  60 MNEF W=52U L=0.65U AD=80P AS=80P PD=80U PS=80U
R7   4  47 24
MN7  47 3  60  60 MNEF W=52U L=0.65U AD=80P AS=80P PD=80U PS=80U
R8   4  48 24
MN8  48 3  60  60 MNEF W=52U L=0.65U AD=80P AS=80P PD=80U PS=80U
R9   4  49 24
MN9  49 3  60  60 MNEF W=52U L=0.65U AD=80P AS=80P PD=80U PS=80U
.ENDS


.SUBCKT pk14 1 3 5 7 9 11 13 15 17 19
+  21 23 25 27
+  2 4 6 8 10 12 14 16 18 20
+  22 24 26 28
* pin resistors SI units, bondwire diameter, resistivity =  2.54E-05,  2.44E-08
* leadframe thickness, resistivity =  1.50E-04,  2.87E-08
R1 1 1001   3.46E-02
R2 3 1003   4.33E-02
R3 5 1005   2.80E-02
R4 7 1007   2.88E-02
R5 9 1009   2.80E-02
R6 11 1011   4.33E-02
R7 13 1013   3.46E-02
R8 15 1015   3.46E-02
R9 17 1017   4.33E-02
R10 19 1019   2.80E-02
R11 21 1021   2.88E-02
R12 23 1023   2.80E-02
R13 25 1025   4.33E-02
R14 27 1027   3.46E-02

* linear inductors leadframe thickness, resistivity =  1.50E-04,  2.87E-08
L1 1001 2   2.32E-09
L2 1003 4   2.04E-09
L3 1005 6   1.36E-09
L4 1007 8   1.38E-09
L5 1009 10   1.36E-09
L6 1011 12   2.04E-09
L7 1013 14   2.32E-09
L8 1015 16   2.32E-09
L9 1017 18   2.04E-09
L10 1019 20   1.36E-09
L11 1021 22   1.38E-09
L12 1023 24   1.36E-09
L13 1025 26   2.04E-09
L14 1027 28   2.31E-09
* mutual inductors small ones pruned
* If all the pins are in series, equivalent L =   2.56E-08  equivalent R =   4.81E-01
* If all the pins are in parallel, equivalent L =   1.24E-10  equivalent R =   2.38E-03
.ENDS pk14

 
***********************************************
*         FAST N-CHANNEL TRANSISTOR           *
*           UCB-3 PARAMETER SET               *
*                 NOV-1995                    *
***********************************************
.MODEL MNEF NMOS
+LEVEL = 3
+KP    = 174E-6
+VTO   = 0.46
+TOX   = 13.5E-9
+NSUB  = 8.9E16
+GAMMA = 0.54
+PHI   = 0.65
+VMAX  = 160E3
+RS    = 5
+RD    = 5
+XJ    = 0.31E-6
+DELTA = 1.46
+THETA = 0.070
+ETA   = 0.025
+KAPPA = 0.0
+WD    = -0.05E-6
************************************************
*        FAST P-CHANNEL TRANSISTOR             *
*           UCB-3 PARAMETER SET                *
*                 NOV-1995                     *
************************************************
.MODEL MPEF PMOS
+LEVEL = 3
+KP    = 67.3E-6
+VTO   = -0.55
+TOX   = 13.5E-9
+NSUB  = 7.9E16
+GAMMA = 0.65
+PHI   = 0.65
+VMAX  = 1.0E6
+RS    = 7.5
+RD    = 7.5
+XJ    = 0.28E-6
+DELTA = 4.80
+THETA = 0.189
+ETA   = 0.055
+KAPPA = 0.0
+WD    = -0.12E-6
============= Model =================

my simbol has 4 pins : 1.pin: input, 2.pin: output, 3.pin: vcc, 4.pin: gnd

vcc= 5 volt , and the input is driven by a clock source of 10 kHz (5V amplitude).

It would be really helpful to me, if you would give it a try. Maybe i miss one step or there is really a bug somewhere.

thanks in the meantime,

daniel

[_user32]

dan.iel,

I tried this myself and I think your circuit and model are correctly entered.  Looking closely I did see a problem with Multisim handling the NXP Level-3 MOSIS mosfets, even in the simplest inverter configuration.  There is a parameter, 'WD=' that is being taken out by Multisim and looking at the MOSIS documentation it is not 'officially' supported in level 3 MOSIS models, so I will need to discuss this with R&D to see how to account for this for these models.  This may or may not be the reason why this is not functioning, but I cannot be sure until R&D takes a look.

I think I have isolated the problem and see below for my schematic showing A) a functional inverter using a known N ch and P ch Mosfet and B) the same inverter configuration with the NXP mosfet models - this was from the core .SUBCKT LVCINVAF model in the INVERT10 model.  

Regards,

Patrick Noonan
Business Development Manager
National Instruments - Electronics Workbench Group
50 Market St. 1-A
S. Portland, ME 04106
Email: patrick.noonan@ni.com
Tel. (207) 892-9130

[_user32]

dan.iel ,

Sorry for the slight delay on getting back to you.  After the internal analysis, it doesn't look like the WD parameter is the culprit (although it may have impact on the sim accuracy).  It looks like we are looking at the old divide by zero phenomenon in the underlying SPICE3F5 due to the KAPPA=0.0 setting in the NXP models.    So I put in a low value of KAPPA=0.001 for the underlying N and P ch MOSFET models.  

Here are the attached circuits running.   (By the way, for the more complex high level "NXP LVC INVERT10 Test" circuit and model, I did need to change the simulation settings to get this to properly converge - note I changed the 4 most common SPICE default settings to change, TMAX time step (incr), RELTOL (incr), RSHUNT (decr) and set integration method to GEAR)...  From the menu: Simulate -> Interactive Simulation Settings to see the specifics.

Regards,

Patrick Noonan
Business Development Manager
National Instruments - Electronics Workbench Group
50 Market St. 1-A
S. Portland, ME 04106
Email: patrick.noonan@ni.com
Tel. (207) 892-9130
Fax. (512) 683-7754