how to pass a Zetex model to Multisim

[samphantom]

Hello there.

I'm using the last version of Multisim 10.0 professional and I love it. The problem is that I do not know many of the tips for passing models from other companies like Zetex to Multisim.

I'm trying to use the model ZXCT1009 from Zetex Spice model and I've tried and tried but with no success, I'm a little slow to understand the process but if someone know how to do it I will appreciated a  lot.

How you do that?  Once I know how it will be too easy to go ahead.

Thank you for any support.

Greetings

swattpeter@live.com

[Fernando_D]

Hello,

Could you post the SPICE model? I'd like to give it a try.

Regards,

[samphantom]

Thank you Fernando

Here is the Spice Model

*
*ZETEX ZXCT1009F Spice Model v2.1 Last revision 02/02/07
*
*
.SUBCKT ZXCT1009F 1 2 3
*
*Pins 1.Load 2.Vin 3.Iout
*
I1 4 3 4uA
R6 4 3 20E6
R1 2 4 Rmod1 1
Q1 4 5 3 LargeN
C1 5 11 3E-9
R5 11 3 10
R2 5 6 10E3
D1 6 8 Dmod
R3 7 6 1
V2 8 3 10
E1 7 3 4 9 1000
V1 10 1 100e-3
I2 9 10 100E-3
R4 9 10 Rmod2 1
.MODEL Dmod D IS=1E-15 BV=20 IBV=1E-3 
.MODEL LargeN NPN IS=3.8E-16 LOT/1/UNIFORM=50% DEV/GAUSS=1%
+ BF=220 LOT/1/UNIFORM=50% DEV/GAUSS=1% NK=.75 IKF=17e-3 VAF=60
+ ISE=1.8E-16 NE=1.4 BR=.7 IKR=3e-2 VAR=7 ISC=5E-12 NC=1.321 RB=300
+ RE=19.7 RC=63.4 CJC=51E-12 MJC=.42 VJC=.595 CJE=.21E-12 MJE=.33
+ VJE=.7 TF=1.5E-10 TR=6E-9 XTF=0.3 VTF=6 ITF=5E-5 XTB=1.17 XTI=5.4
+ KF=2E-13 AF=1.4
.MODEL Rmod1 RES (R=99.5 TC1=1E-3 TC2=1E-5 LOT/1/UNIFORM=1% DEV/GAUSS=0.5%)
.MODEL Rmod2 RES (R=1 LOT/1/UNIFORM=1% DEV/GAUSS=0.5%)
.ENDS 
*
*$
*
*                (c)  2007 Zetex Semiconductors plc
*
*   The copyright in these models  and  the designs embodied belong
*   to Zetex Semiconductors plc (" Zetex ").  They  are  supplied
*   free of charge by Zetex for the purpose of research and design
*   and may be used or copied intact  (including this notice)  for
*   that purpose only.  All other rights are reserved. The models
*   are believed accurate but  no condition  or warranty  as to their
*   merchantability or fitness for purpose is given and no liability
*   in respect of any use is accepted by Zetex PLC, its distributors
*   or agents.
*
*   Zetex Semiconductors plc, Zetex Technology Park, Chadderton,
*   Oldham, United Kingdom, OL9 9LL

 This is the web page as well if you want to see the spice model

http://www.diodes.com/products/catalog/detail.php?item-id=1663

I hope you can make it work, because that will be a huge help for me.

Regards

[_user32]

samphantom,

I got it to work.  See attached.  In general here are just a couple of tips for you when importing models...

1. Keep a close watch to the header comments that indicate the SPICE model pin order - this order must correctly match the symbol.  In this case the header in the spice file has the following comment...

.SUBCKT ZXCT1009F 1 2 3

*Pins 1.Load 2.Vin 3.Iout ->

Irregardless of the order of the symbols or footprint pins, you'll need to match this to the symbol (note: in this case the SOT23 pin1 is Iout - so the pin order has no bearing on the SPICE model data.  When matched to the symbol the circuit will function, however there are still some errors, so...

2. Multisim flagged a few errors in this model.  When this happens you can look at the results in the Simulation Tab to track down these errors in the model.  I am not sure which simulator this model was designed for but the following model parameters are not defined in the SPICE3F5 version that Multisim uses: 

"LOT/1/UNIFORM=X%" and "DEV/GAUSS=X%"

Take these out and once removed the simulation will work as expected.

See circuit below...

Regards,

Patrick Noonan
Business Development Manager
National Instruments - Electronics Workbench Group
50 Market St. 1-A
S. Portland, ME 04106
Email: patrick.noonan@ni.com
Tel. (207) 892-9130
Fax. (207) 892-9508 

[samphantom]

Thank you user 32 but I did all that you said and with no success, here is the spice file modificated:

*
*ZETEX ZXCT1009F Spice Model v2.1 Last revision 02/02/07
*
*
.SUBCKT ZXCT1009F 1 2 3
*
*Pins 1.Iout 2.Vin 3.Load
*
I1 4 3 4uA
R6 4 3 20E6
R1 2 4 Rmod1 1
Q1 4 5 3 LargeN
C1 5 11 3E-9
R5 11 3 10
R2 5 6 10E3
D1 6 8 Dmod
R3 7 6 1
V2 8 3 10
E1 7 3 4 9 1000
V1 10 1 100e-3
I2 9 10 100E-3
R4 9 10 Rmod2 1
.MODEL Dmod D IS=1E-15 BV=20 IBV=1E-3
.MODEL LargeN NPN IS=3.8E-16
+ BF=220  NK=.75 IKF=17e-3 VAF=60
+ ISE=1.8E-16 NE=1.4 BR=.7 IKR=3e-2 VAR=7 ISC=5E-12 NC=1.321 RB=300
+ RE=19.7 RC=63.4 CJC=51E-12 MJC=.42 VJC=.595 CJE=.21E-12 MJE=.33
+ VJE=.7 TF=1.5E-10 TR=6E-9 XTF=0.3 VTF=6 ITF=5E-5 XTB=1.17 XTI=5.4
+ KF=2E-13 AF=1.4
.MODEL Rmod1 RES (R=99.5 TC1=1E-3 TC2=1E-5)
.MODEL Rmod2 RES (R=1)
.ENDS
*
*$
*
*                (c)  2007 Zetex Semiconductors plc
*
*   The copyright in these models  and  the designs embodied belong
*   to Zetex Semiconductors plc (" Zetex ").  They  are  supplied
*   free of charge by Zetex for the purpose of research and design
*   and may be used or copied intact  (including this notice)  for
*   that purpose only.  All other rights are reserved. The models
*   are believed accurate but  no condition  or warranty  as to their
*   merchantability or fitness for purpose is given and no liability
*   in respect of any use is accepted by Zetex PLC, its distributors
*   or agents.
*
*   Zetex Semiconductors plc, Zetex Technology Park, Chadderton,
*   Oldham, United Kingdom, OL9 9LL

 The simulator that this spice model uses is Zetec Circuit Simulator 5.40

I was able to open your model with no problems but when I did mine I could not open, what is wrong?

Thank you for your help.

[samphantom]

There is also another model that I want to use, is Si1012R from Vishay and has the spice model as well and I try to pass to Multisim and it says that the file was not recognized as a valid file format.

This is the spice model

*July 27, 2005
*Doc. ID: 77166, S-51298, Rev. C
.SUBCKT Si1012R 4 1 2
M1   3 5 2 2 NMOS W=29549u L=0.50u
M2   2 5 2 4 PMOS W=29549u L=0.95u
R1   4 3     RTEMP 130E-3
CGS  5 2     41E-12
DBD  2 4     DBD
XESD 1 5 2   Si1012R_ESD
************************************************************ 
.MODEL  NMOS         NMOS (LEVEL  = 3        TOX    = 1.7E-8
+ RS     = 280E-3          RD     = 0        NSUB   = 1.5E17  
+ KP     = 5.6E-5          UO     = 650            
+ VMAX   = 0               XJ     = 5E-7     KAPPA  = 10E-2
+ ETA    = 1E-4            TPG    = 1 
+ IS     = 0               LD     = 0                            
+ CGSO   = 0               CGDO   = 0        CGBO   = 0
+ TLEV   = 1               BEX    = -1.5     TCV    = 1.8E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
************************************************************ 
.MODEL  PMOS         PMOS (LEVEL  = 3        TOX    = 1.7E-8
+NSUB    = 2.6E16          TPG    = -1)  
************************************************************ 
.MODEL DBD D (CJO=32E-12 VJ=0.38 M=0.3
+RS=1 FC=0.1 IS=1E-12 TT=4E-8 N=1 BV=20.5)
************************************************************
.MODEL RTEMP R (TC1=10E-3  TC2=5.5E-6)
************************************************************ 
.ENDS Si1012R
.subckt Si1012R_ESD 1 5 2
rd1 1 6 1 TC=300
d1 6 2 dleak M=1
.MODEL dleak d (IS=3E-9 XTI=350 EG=1.17 TREF=25 TCV=0 N=34 BV=6.4)
rd2 1 7 34 TC=-0.0002
d2 8 7 dout M=1
d3 8 2 dout M=1
.MODEL dout D (IS=5.1E-9 XTI=-35 EG=1.17 TREF=25 TCV=3.6E-3 N=2 BV=6.38)
rpoly 1 5 100 TC=0.001
rd4 5 9 100 TC=-0.015
d4 10 9 din M=1
d5 10 2 din M=1
.MODEL din D (IS=5.1E-9 XTI=-30 EG=1.17 TREF=25 TCV=1.1E-3 N=1.5 BV=6.25)
.ends Si1012R_ESD 

I need this model to complete the circuit before making it.

Does anyone knows how to pass it to Multisim?

Thank you for your time and patience.

[_user32]

samphantom ,

Please post your component for the ZXCT1009F and I can look at the component to see what is happening...   Also please confirm that the version of the component for the circuit ZXCT1009F Test Circuit.ms10 built is working?

I'll take a look at the Si1012R and repost after I have some additional time to look at the model data.

Regards,

Patrick Noonan
Business Development Manager
National Instruments - Electronics Workbench Group
50 Market St. 1-A
S. Portland, ME 04106
Email: patrick.noonan@ni.com
Tel. (207) 892-9130
Fax. (207) 892-9508 

[samphantom]

Hello user32

Yes, I confirm that I'm using the last version of Multisim10.1 and that the circuit for ZXCT1009 is working fine and I'm using it.

But I do not know what you mean by: "Please post your component for the ZXCT1009F and I can look at the component to see what is happening."

Do you mean to post the PDF file of the component and circuit which are here?:

http://www.diodes.com/datasheets/ZXCT1009.pdf

or what do you mean by that.

Anyways let me know and thank you for your time for the other transistor Si1012R.

By the way, do you have some Multisim model for an photoisolator? like PC817X or alike?

Thank you again. 

[_user32]

samphantom ,

Here is the Si1012R component.  

Regarding my 'please post', if you cannot get a model to work, post your circuit with the component you have attempted to create and then we could take a look at how you've created it and can give you additional pointers with the component / model creation process.

Here are the details for the Si1012R N channel Mosfet. In this model there are no comments (indicated by a *) in the model header information telling how this model is connected, so it is a little trickier, the .SUBCKT header is as follow, the question is which nets (4, 1, 2) connect into the Gate, Drain and Source for this N Channel Mosfet?

.SUBCKT SI1012R   4 1 2

How can you tell?  Well if you look at the model there is a Diode called "DBD  2 4     DBD" - by this is probably the Drain Body Diode and it is telling us that net 2 and net 4 are the Drain and Source (or vice versa) - this means by deductive reasoning that net 1 is the Gate.   Also if you look at the Capacitor labeled: "CGS  5 2     41E-12", this is likely the Capacitor b/w Gate/Source so it is telling you that the Gate and Source are connected, to either pins 5 and 2 - since we know the Gate is net 1, net 2 is the Source and therefore the Drain has to be net 4...   Also this means there are some additional connections between net 1 (external Gate) and net 5 (internal pin connecting to Gate through some additional circuit network - this is irrelevent for pin mapping).

so the externally connected model pin order is as follows:

position 1 (net 4) ... D (drain)

position 2 (net 1) ... G (gate)

position 3 (net 2) ... S (source)

Using the Multisim Component Wizard, the position/order of the nets as given in the .subckt header is important, not the name.  So in step 7 of 8 (I created both footprint and model) where you associate the symbol pins to the model pins you will need to rearrange the order corresponding to the positioning above (the wizard will only give you 1, 2, 3 or NC for choices).

Hopefully this helps...

Regarding Optocouplers/Photoisolators, refer to the following Group/Family in the Master DB -> Misc -> OPTOCOUPLER.   There is also a virtual Optocoupler in the MISC_VIRTUAL family within the Misc grouping...

Regards,

Patrick Noonan
Business Development Manager
National Instruments - Electronics Workbench Group
50 Market St. 1-A
S. Portland, ME 04106
Email: patrick.noonan@ni.com
Tel. (207) 892-9130
Fax. (207) 892-9508 

[samphantom]

WOW, you just simple blow my mind.

I wish to have at least the half knowledge to create some circuits.

Thank you so much for your help, time and patience.

The model that you did is working perfectly, what I'm trying to do is to simulate the charging of a battery through a battery charger (which I do not know if there is a model for this, and I'm changing the value of a power supply), the battery is 12v @ 18Ah. And the circuit ZXCT1009 was intended to tell me if the battery has been charged already, (probably there are another ways to implement a current sensor monitor).

All I want is the current sensor send a signal through a led to tell me that the battery is already charged because the charger has already a light indicator to tell if the battery is ready or not and I do not have that indicator in my box, so that is why I wanted a current sensor.

I will looking for those optocoupler models, I try but I did not see them, probably I'm blind, anyways, thank you again for your help and have a nice day.